_realname=qt-style-globalqss

mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
msys2_repository_url='https://github.com/luigifab/globalqss'

pkgbase=mingw-w64-$_realname
pkgname=("${MINGW_PACKAGE_PREFIX}-qt5-style-globalqss" "${MINGW_PACKAGE_PREFIX}-qt6-style-globalqss")
pkgver=1.2.0
pkgrel=1
pkgdesc='GlobalQSS style engine for Qt'
url='https://github.com/luigifab/globalqss'
license=('spdx:GPL-2.0-or-later')
arch=('any')
makedepends=("${MINGW_PACKAGE_PREFIX}-cmake" "${MINGW_PACKAGE_PREFIX}-cc" "${MINGW_PACKAGE_PREFIX}-qt5-base>=5.10.0" "${MINGW_PACKAGE_PREFIX}-qt6-base")
source=("https://github.com/luigifab/globalqss/archive/v${pkgver}/globalqss-${pkgver}.tar.gz")
sha256sums=('SKIP')

prepare() {
  mv "globalqss-$pkgver" "$pkgbase-$pkgver"
}

build() {
  cd "$pkgbase-$pkgver"
  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
    "${MINGW_PREFIX}/bin/cmake" -S src-5 -B build-qt5 \
      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
      -DCMAKE_BUILD_TYPE=Release
  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
    "${MINGW_PREFIX}/bin/cmake" -S src-6 -B build-qt6 \
      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
      -DCMAKE_BUILD_TYPE=Release
  "${MINGW_PREFIX}/bin/cmake" --build build-qt5
  "${MINGW_PREFIX}/bin/cmake" --build build-qt6
}

package_qt5-style-globalqss() {
  pkgdesc+=" 5 (mingw-w64)"
  depends+=("${MINGW_PACKAGE_PREFIX}-qt5-base>=5.10.0")
  cd "$pkgbase-$pkgver"
  DESTDIR="$pkgdir" "${MINGW_PREFIX}/bin/cmake" --install build-qt5
  #install -Dpm 644 README.md "$pkgdir/${MINGW_PREFIX}/share/doc/$pkgname/README.md"
  install -Dpm 644 LICENSE "$pkgdir/${MINGW_PREFIX}/share/licenses/$pkgname/LICENSE"
}

package_qt6-style-globalqss() {
  pkgdesc+=" 6 (mingw-w64)"
  depends+=("${MINGW_PACKAGE_PREFIX}-qt6-base")
  cd "$pkgbase-$pkgver"
  DESTDIR="$pkgdir" "${MINGW_PREFIX}/bin/cmake" --install build-qt6
  #install -Dpm 644 README.md "$pkgdir/${MINGW_PREFIX}/share/doc/$pkgname/README.md"
  install -Dpm 644 LICENSE "$pkgdir/${MINGW_PREFIX}/share/licenses/$pkgname/LICENSE"
}

# template start; name=mingw-w64-splitpkg-wrappers; version=1.0;
# vim: set ft=bash :

# generate wrappers
for _name in "${pkgname[@]}"; do
  _short="package_${_name#${MINGW_PACKAGE_PREFIX}-}"
  _func="$(declare -f "${_short}")"
  eval "${_func/#${_short}/package_${_name}}"
done
# template end;